.model small
.code

TEST_WRITE_DECIMAL PROC
  mov   DX,12345
  CALL  WRITE_DECIMAL
  int   20h                 ;Return to DOS
TEST_WRITE_DECIMAL ENDP

  PUBLIC WRITE_DECIMAL
;-----------------------------------------------------------------------;
; This procedure writes a 16-bit, unsigned number in decimal notation.  ;
;                                                                       ;
; On Entry:  DX N:16-bit, unsigned number.                              ;
;                                                                       ;
;  Uses:     WRITE_HEX_DIGIT                                            ;
;-----------------------------------------------------------------------;
WRITE_DECIMAL PROC NEAR
  PUSH AX                   ;Save registers used here
  PUSH CX
  PUSH DX
  PUSH SI
  MOV  AX,DX
  MOV  SI,10                ;Will divide by 10 using SI
  XOR  CX,CX                ;Count of digits placed on stack
NON_ZERO:
  XOR  DX,DX                ;Set upper word of N to 0
  DIV  SI                   ;Calculate n/10 and (N mod 10)
  PUSH DX                   ;Push one digit onto the stack
  INC  CX                   ;One more digit added
  OR   AX,AX                ;n =0 yet?
  JNE  NON_ZERO             ;nope, continue
WRITE_DIGIT_LOOP:
  POP  DX                   ;Get the digits in reverse order
  CALL WRITE_HEX_DIGIT
  LOOP WRITE_DIGIT_LOOP
END_DECIMAL:
  POP SI
  POP DX
  POP CX
  POP AX
  RET
WRITE_DECIMAL ENDP

   PUBLIC WRITE_HEX
;-----------------------------------------------------------------------;
; This procedure converts the byte in the DL register to hex and writes ;
; the two hex digits at the current cursor position.                    ;
;                                                                       ;
; On Entry;  DL  Byte to be converted to hex.                           ;
; Uses:      WRITE_HEX_DIGIT                                            ;
;-----------------------------------------------------------------------;
WRITE_HEX PROC              ;Entry point
  push cx                   ;Save registers used in this procedure
  push dx
  mov  dh,dl                ;Make a copy of byte
  mov  cx,4                 ;Get the upper nibble in DL
  shr  dl,cl                
  call write_hex_digit      ;Display first hex digit
  mov  dl,dh                ;Get lower nibble into DL
  and  dl,0Fh               ;Remove the upper nibble
  call write_hex_digit      ;Display second hex digit
  pop  dx
  pop  cx
  ret
WRITE_HEX ENDP
 
  PUBLIC WRITE_HEX_DIGIT
;-----------------------------------------------------------------------;
; This procedure converts the lower 4 bits of DL to a hex digit and     ;
; writes it to the screen.                                              ;
;                                                                       ;
; On Entry;  DL Lower 4 bits contain number to be printed               ;
;               in hex.                                                 ;
;                                                                       ;
; Uses:      WRITE_CHAR                                                 ;
;-----------------------------------------------------------------------;
WRITE_HEX_DIGIT  PROC
  PUSH DX                  ;Save registers used
  CMP DL, 10               ;Is this nibble <10?
  JAE HEX_LETTER           ;No, convert to letter
  ADD DL,"0"               ;Yes, convert to a digit
  JMP Short WRITE_DIGIT    ;Now write this character
HEX_LETTER:
  ADD DL,"A"-10            ;Convert to hex letter
WRITE_DIGIT:
  CALL WRITE_CHAR          ;Display the letter on the screen
  POP DX                   ;Restore old value of DX
  RET
WRITE_HEX_DIGIT ENDP

  PUBLIC WRITE_CHAR
;-----------------------------------------------------------------------;
; This procedure prints a character on the screen using the DOS         ;
; function call.                                                        ;
;                                                                       ;
; On Entry:  DL Byte to print on the screen.                            ;
;-----------------------------------------------------------------------;
WRITE_CHAR PROC
  PUSH AX                  
  MOV  AH,2                ;Call for character output
  INT 21h                  ;Output character in DL 
  POP AX                   ;Restore old value in AX
  RET                      ;And return
WRITE_CHAR ENDP

  END TEST_WRITE_DECIMAL